jenkins pipeline 에서 데이터베이스 테스트 환경 세팅 자동화하기 (테스트용 데이터베이스 컨테이너 사용)

pipeline {
    agent {
        docker {
          // 이미지는 본인 상황에 맞게 변경해줘야 함.
          // 단순히 docker-cli 사용을 위한 이미지.
          image 'docker-cli'
        }
    }

    environment {
        GIT_URL = "YOUR_GIT_URL"
    }

    stages {
        stage ('check network bridge') {
            steps {
                script {
                    // 있으면 사용하고 없으면 생성하도록 처리하였다.
                    sh '''
                    docker network inspect {NETWORK_NAME} >/dev/null 2>&1 || \
                    docker network create --driver bridge {NETWORK_NAME}
                    '''
                }
            }
        }
        stage ('start test') {
            agent {
                docker {
                  // 이미지는 본인 상황에 맞게 변경해줘야 함.
                  // Gradle 실행을 위한 자바 환경 이미지가 필요.
                  // 나의 경우에는 아래에서 데이터베이스 health 체크용으로 `docker exec` 명령어를 수행하도록 하기 위해 docker cli 추가 해서 사용하였다.
                  image 'GRADLE'
                  args '-v /var/run/docker.sock:/var/run/docker.sock --network {NETWORK_NAME}'
                }
            }
            stages {
                stage ('checkout') {
                    steps {
                        script {
                            def scmVars = checkout([
                                $class: 'GitSCM',
                                branches: [[name: "release/${params.VERSION}"]],
                                doGenerateSubmoduleConfigurations: false,
                                extensions: [[
                                    $class: 'SubmoduleOption',
                                    disableSubmodules: false,
                                    parentCredentials: true,
                                    recursiveSubmodules: true,
                                    reference: '',
                                    trackingSubmodules: false
                                ]],
                                submoduleCfg: [],
                                userRemoteConfigs: [[
                                    credentialsId: 'YOUR_CREDENTIAL_ID',
                                    url: env.GIT_URL
                                ]]
                            ])
                        }
                    }
                }
                stage ('run integration test') {
                    steps {
                        script {
                            docker.image('mysql:8.0.33')
                                .withRun('--network {NETWORK_NAME}'
                                + ' -e MYSQL_ROOT_PASSWORD={YOUR_PASSWORD}'
                                + ' -e MYSQL_DATABASE={YOUR_DATABASE}') { c ->

                                // Wait until mysql is up
                                sh "while ! docker exec ${c.id} mysqladmin --user=root --password={YOUR_PASSWORD} --host '127.0.0.1' ping --silent ; do sleep 5; done;"

                                sh "GRADLE_USER_HOME=./.gradle DATASOURCE_HOST=${c.id.substring(0,12)} DATASOURCE_PORT=3306 ./gradlew integrationTest"
                                // integrationTest는 커스텀 task이다.
                            }
                        }
                    }
                }
            }
        }
    }

//   post {
//     always {
//         script {
//             ...
//         }
//     }
//     ...
//   }
}